'----------------------------------------------
' Edit these values
'----------------------------------------------

' Backup folder - this is directory the files are saved to. Do 
' NOT use a trailing backslash. You MUST create the folder
' before running the script.
strBackupFolder = "C:\OCS 2007 Configuration"

' Global & Pool Level File Name - this is the file name of the
' XML used for storing global and pool level settings
strGlobalPoolLevelFileName = "ocs-2007-global-pool-settings.xml"

' Global & Pool Level File Name - this is the file name of the
' XML used for storing machine level settings.
strMachineLevelFileName = "ocs-2007-machine-settings.xml"

' Global & Pool Level Task Name
strGlobalPoolTaskName = "OCS 2007 - Global and Pool Level Settings Backup"

' Global & Pool Level Task Start Time
strGlobalPoolTaskStart = "04:00"

' Machine Level Task Name
strMachineTaskName = "OCS 2007 - Machine Level Settings Backup"

' Machine Level Task Start Time
strMachineTaskStart = "04:05"

' SQL Backup Task Name
strSQLBackupTaskName = "OCS 2007 - Database Backup"

' SQL Backup Start Time
strSQLBackupTaskStart = "04:10"

' SQL Backup Script Name
strSQLBackupScriptName = "ocs-backup-job.sql"

' SQL Backup File Name
strSQLBackupFileName = "rtc-full.bak"

'----------------------------------------------
' You can probably leave this section alone
'----------------------------------------------

set objFSO = CreateObject ("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("" & strBackupFolder & "\" & strSQLBackupScriptName & "",True)
objFile.WriteLine("BACKUP DATABASE [rtc] TO  DISK = N'" & strBackupFolder & "\" & strSQLBackupFileName & "' WITH NOFORMAT, INIT,  NAME = N'rtc-Full Database Backup', SKIP, NOREWIND, NOUNLOAD,  STATS = 10")
objFile.WriteLine("Go")
objFile.Close

'Create an array of OCS Pools
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colOCSPools = objWMIService.ExecQuery("Select * from MSFT_SIPPoolSetting")

'Get name of OCS pool
For Each objOCSPool in colOCSPools 
  strOCSPool = objOCSPool.pooldisplayname
Next

'Create task for global and pool settings backup
Set objShell = WScript.CreateObject("WScript.Shell")
taskParameters = "/create /sc daily /st " & strGlobalPoolTaskStart & " /tr ""\""%programfiles%\Common Files\Microsoft Office Communications Server 2007\LCSCmd.exe\""/config /action:export /level:global,pool /configfile:\""" & strBackupFolder & "\" & strGlobalPoolLevelFileName & "\"" /poolname:" & strOCSPool & """ /TN """ & strGlobalPoolTaskName &""""
objShell.Run "schtasks.exe " & taskParameters

'Create task for machine settings backup
taskParameters = "/create /sc daily /st " & strMachineTaskStart & " /tr ""\""%programfiles%\Common Files\Microsoft Office Communications Server 2007\LCSCmd.exe\""/config /action:export /level:machine /configfile:\""" & strBackupFolder & "\" & strMachineLevelFileName & "\"" /poolname:" & strOCSPool & """ /TN """ & strMachineTaskName &""""
objShell.Run "schtasks.exe " & taskParameters

'Create task for SQL backup 
taskParameters = "/create /sc daily /st " & strSQLBackupTaskStart & " /tr ""sqlcmd.exe -e -s .\RTC -i \""" & strBackupFolder & "\" & strSQLBackupScriptName & "\"""" /TN """ & strSQLBackupTaskName &""""
objShell.Run "schtasks.exe " & taskParameters